#!/bin/csh

# c-shell script to calculate lag correlation
# between PC1 and PC2 from EOF

# !!!!!! What should be modified !!!!!!
# HHH  : home directory
# var  : name of data
# DDD  : number of days per 1 year (for models using 360 day calendar)
# TTT  : number of total time (in day) - total period
# BYY  : first year (e.g. 1979)
# NYR  : number of years (e.g. 27 for 1979-2005)
# NYR1 : NYR - 1
# LYR  : whether the data has leap year or not
#  (e.g. 1 : leap year, 0 : no leap year)
# LNX  : whether the machine is linux or not
#  This is for the record length problem.
#  (e.g. 4 : linux machine, 1 : other machine)
# MMM  : missing value
# !!!!!! What should be modified !!!!!!

#enver setenv HHH /jdata4/cdl/kim/msd
 setenv HHH ~/work/programs/MJOWG/msd




 foreach var ( olr_av u850_n1 u200_n1 )

 setenv DDD 365
 setenv BYY 1979
 setenv LYR 1
 setenv LNX 1
 setenv MMM -999.
 setenv PPP 19790101_20051231

@ NYR = 27
@ NYR1 = $NYR - 1


 cd $HHH/level_1/$var

# source directory
 mkdir -p src/pcl
 cd src/pcl

 cp -f $HHH/level_1/sample/pcl/input.nml.sample .
 cp -f $HHH/level_1/sample/pcl/llreg_2d.f90 .

 foreach sea ( win sum )

 if ( $sea == 'win' ) then

  setenv SNN 1

  if ( $var == 'olr_av' ) then
   setenv TTT 4713
   setenv SN1 1
   setenv SN2 -1
  else if ( $var == 'u850_n1' ) then
   setenv TTT 4713
   setenv SN1 1
   setenv SN2 1
  else if ( $var == 'u200_n1' ) then
   setenv TTT 4713
   setenv SN1 -1
   setenv SN2 -1
  endif

 else if ( $sea == 'sum' ) then

  setenv SNN 2

  if ( $var == 'olr_av' ) then
   setenv TTT 4968
   setenv SN1 1
   setenv SN2 -1
  else if ( $var == 'u850_n1' ) then
   setenv TTT 4968
   setenv SN1 -1
   setenv SN2 1
  else if ( $var == 'u200_n1' ) then
   setenv TTT 4968
   setenv SN1 -1
   setenv SN2 -1
  endif

 endif

 sed "s#homedir#$HHH#g"         input.nml.sample > tmp1
 sed "s/variable/$var/g"                    tmp1 > tmp2
 sed "s/num_d/$DDD/g"                       tmp2 > tmp1
 sed "s/num_t/$TTT/g"                       tmp1 > tmp2
 sed "s/num_r/$NYR1/g"                      tmp2 > tmp1
 sed "s/sea_num/$SNN/g"                     tmp1 > tmp2
 sed "s/sea_name/$sea/g"                    tmp2 > tmp1
 sed "s/beg_year/$BYY/g"                    tmp1 > tmp2
 sed "s/leap_year/$LYR/g"                   tmp2 > tmp1
 sed "s/linux_recl/$LNX/g"                  tmp1 > tmp2
 sed "s/missing/$MMM/g"                     tmp2 > tmp1
 sed "s/sign1/$SN1/g"                       tmp1 > tmp2
 sed "s/sign2/$SN2/g"                       tmp2 > input.nml

f95 -ffree-line-length-none llreg_2d.f90
a.out
rm -f a.out

end 

end