      PROGRAM FRANGE
      IMPLICIT NONE
C
C  hycom_range - Usage:  hycom_range file.a idm jdm [ip jp]
C
C                 prints min/max for each (1:idm,1:jdm) array in file.a
C                 a(ip,jp) is also printed if ip and jp are present
C
C  file.a is assumed to contain idm*jdm 32-bit IEEE real values for
C   each array, in standard f77 element order, followed by padding
C   to a multiple of 4096 32-bit words, but otherwise with no control
C   bytes/words, and input values of 2.0**100 indicating a data void.
C
C  this version for "serial" Unix systems.
C
C  Alan J. Wallcraft,  Naval Research Laboratory,  January 2001.
C  Updated to skip NaN's, September 2023.
C
      REAL*4, ALLOCATABLE :: A(:,:)
      REAL*4              :: PAD(4096)
      INTEGER IOS
      INTEGER      IARGC
      INTEGER      NARG
      CHARACTER*240 CARG
C
      INTEGER      IDM,JDM,NPAD,IP,JP
      CHARACTER*240 CFILE
C
C     READ ARGUMENTS.
C
      NARG = IARGC()
C
      IF     (NARG.EQ.3) THEN
        CALL GETARG(1,CFILE)
        CALL GETARG(2,CARG)
        READ(CARG,*) IDM
        CALL GETARG(3,CARG)
        READ(CARG,*) JDM
*       WRITE(6,*) 'hycom_range ',trim(cfile),idm,jdm
        IP = 0
        JP = 0
      ELSEIF (NARG.EQ.5) THEN
        CALL GETARG(1,CFILE)
        CALL GETARG(2,CARG)
        READ(CARG,*) IDM
        CALL GETARG(3,CARG)
        READ(CARG,*) JDM
        CALL GETARG(4,CARG)
        READ(CARG,*) IP
        CALL GETARG(5,CARG)
        READ(CARG,*) JP
*       WRITE(6,*) 'hycom_range ',trim(cfile),idm,jdm,ip,jp
      ELSE
        WRITE(6,*) 'Usage: hycom_range file.a idm jdm [ip jp]'
        CALL EXIT(1)
      ENDIF
C
      NPAD = 4096 - MOD(IDM*JDM,4096)
      IF     (NPAD.EQ.4096) THEN
        NPAD = 0
      ENDIF
*     WRITE(6,*) 'idm*jdm,npad = ',idm*jdm,npad
C
      ALLOCATE( A(IDM,JDM), STAT=IOS )
      IF     (IOS.NE.0) THEN
        WRITE(6,*) 'Error in hycom_range: could not allocate ',
     +             IDM*JDM,' words'
        CALL EXIT(2)
      ENDIF
C
      CALL RANGE(A,IDM,JDM,PAD,NPAD, IP,JP, CFILE)
      CALL EXIT(0)
      END
      SUBROUTINE RANGE(A,IDM,JDM, PAD,NPAD, IP,JP, CFILE)
      IMPLICIT NONE
C
      REAL*4     SPVAL
      PARAMETER (SPVAL=2.0**100)
C
      CHARACTER*240 CFILE
      INTEGER      IDM,JDM,NPAD,IP,JP
      REAL*4       A(IDM,JDM),PAD(NPAD)
C
C     MOST OF WORK IS DONE HERE.
C
#ifdef sun
      INTEGER      IR_ISNAN
C
#endif
      CHARACTER*18 CIPJP,CASN
      INTEGER      LEN_TRIM
      INTEGER      I,J,K,IOS,NRECL
      REAL*4       AMN,AMX
#ifdef CRAY
      INTEGER*8    IU8,IOS8
#endif
C
      IF     (MIN(IP,JP).GT.0) THEN
        WRITE(CIPJP,6000) IP,JP
 6000   FORMAT('    (',I4,',',I4,') = ')
      ENDIF
C
      INQUIRE( IOLENGTH=NRECL) A,PAD
*     WRITE(6,*) 'nrecl = ',nrecl
#ifdef CRAY
#ifdef t3e
      IF     (MOD(NRECL,4096).EQ.0) THEN
        WRITE(CASN,8000) NRECL/4096
 8000   FORMAT('-F cachea:',I4.4,':1:0')
        IU8 = 11
        CALL ASNUNIT(IU8,CASN,IOS8)
        IF     (IOS8.NE.0) THEN
          write(6,*) 'Error: can''t asnunit 11'
          write(6,*) 'ios  = ',ios8
          write(6,*) 'casn = ',casn
          CALL EXIT(5)
        ENDIF
      ENDIF
#else
      CALL ASNUNIT(11,'-F syscall -N ieee',IOS)
      IF     (IOS.NE.0) THEN
        write(6,*) 'Error: can''t asnunit 11'
        write(6,*) 'ios = ',ios
        CALL EXIT(5)
      ENDIF
#endif
#endif
      OPEN(UNIT=11, FILE=CFILE, FORM='UNFORMATTED', STATUS='OLD',
     +         ACCESS='DIRECT', RECL=NRECL, IOSTAT=IOS)
      IF     (IOS.NE.0) THEN
        write(6,*) 'Error: can''t open ',CFILE(1:LEN_TRIM(CFILE))
        write(6,*) 'ios   = ',ios
        write(6,*) 'nrecl = ',nrecl
        CALL EXIT(3)
      ENDIF
C
      DO 110 K= 1,9999
        READ(11,REC=K,IOSTAT=IOS) A
#ifdef ENDIAN_IO
        CALL ENDIAN_SWAP(A,IDM*JDM)
#endif
        IF     (IOS.NE.0) THEN
          IF     (K.EQ.1) THEN
            WRITE(6,*) 'can''t read ',CFILE(1:LEN_TRIM(CFILE))
            CALL EXIT(4)
          ELSE
            GOTO 1110
          ENDIF
        ENDIF
        AMN =  SPVAL
        AMX = -SPVAL
        DO 210 J= 1,JDM
          DO 212 I= 1,IDM
#ifdef sun
            IF     (IR_ISNAN(A(I,J)).NE.1) THEN
              IF     (A(I,J).NE.SPVAL) THEN
               IF     (A(I,J).LT.AMN) THEN
                  AMN = A(I,J)
                ENDIF
                IF     (A(I,J).GT.AMX) THEN
                  AMX = A(I,J)
                ENDIF
              ENDIF
            ENDIF
#else
            IF     (A(I,J).NE.SPVAL) THEN
              IF     (A(I,J).LT.AMN) THEN
                AMN = A(I,J)
              ENDIF
              IF     (A(I,J).GT.AMX) THEN
                AMX = A(I,J)
              ENDIF
            ENDIF
#endif
  212     CONTINUE
  210   CONTINUE
        IF     (MIN(IP,JP).LE.0) THEN
          WRITE(6,'(a,1p2g16.8)')
     &       'min, max = ',AMN,AMX
        ELSE
          WRITE(6,'(a,1p2g16.8,a,g16.8)')
     &      'min, max = ',AMN,AMX,CIPJP,A(IP,JP)
        ENDIF
  110 CONTINUE
 1110 CONTINUE
      WRITE(6,*) 
      WRITE(6,*) K-1,' FIELDS PROCESSED'
      WRITE(6,*) 
      RETURN
      END
